With this SPARQL endpoint you can query the Academia/Industry DynAmics Knowledge Graph. We encourage all users to familiarise with the AIDA Data Model (Read More) before running queries with this SPARQL endpoint.
A public SPARQL endpoint for querying AIDA KG is available at http://aida.kmi.open.ac.uk/sparqlendpoint.

Examples of queries

Here you can find a handful of examples to kick start your AIDA exploration.

The following performs a describe query for the paper with id 2040986908.
DESCRIBE <http://aida.kmi.open.ac.uk/resource/2040986908>


The following query returns all papers written by authors from the industrial sector computing and it associated with the topic robotics:
PREFIX aida-ont:<http://aida.kmi.open.ac.uk/ontology#>
PREFIX aida:<http://aida.kmi.open.ac.uk/resource/>
PREFIX aidaDB: <http://aida.kmi.open.ac.uk/resource/DBpedia/>
PREFIX cso: <http://cso.kmi.open.ac.uk/topics/>
    
SELECT ?paperId
FROM <http://aida.kmi.open.ac.uk/resource>
WHERE {
    ?paperId aida-ont:hasIndustrialSector aida:computing_and_it .
    ?paperId aida-ont:hasTopic cso:robotics .
}
LIMIT 20


The following query counts how many papers have been written by authors from an industrial affiliation.
PREFIX aida:<http://aida.kmi.open.ac.uk/ontology#>
SELECT (COUNT(?sub) as ?count)
FROM <http://aida.kmi.open.ac.uk/resource>
WHERE {
    ?sub aida:hasAffiliationType "industry"
}


The next query counts how many authors are affiliated with The Open University.
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX schema:<http://schema.org/>
SELECT (COUNT(DISTINCT(?sub)) as ?count)
FROM <http://aida.kmi.open.ac.uk/resource>
WHERE {
    ?sub schema:memberOf ?aff .
    ?aff foaf:name "the_open_university"
}


The following query returns the industrial sectors of all the papers having Semantic Web as a topic.
PREFIX aida:<http://aida.kmi.open.ac.uk/ontology#>
PREFIX cso: <http://cso.kmi.open.ac.uk/topics/>
SELECT DISTINCT ?ind
FROM <http://aida.kmi.open.ac.uk/resource>
WHERE {
    ?sub aida:hasTopic cso:semantic_web .
    ?sub aida:hasIndustrialSector ?ind
}


The following query returns the papers associated with the topic Semantic Web and written in collaboration by authors from industry and academia, where those from academia are more than 80%.
PREFIX aida:<http://aida.kmi.open.ac.uk/ontology#>
PREFIX cso: <http://cso.kmi.open.ac.uk/topics/>
PREFIX schema: <http://schema.org/>
SELECT ?paper ?ind (count(?author) as ?nauthor)
FROM <http://aida.kmi.open.ac.uk/resource>
WHERE {
    ?paper aida:hasTopic cso:semantic_web .
    ?paper aida:hasIndustrialSector ?ind .
    ?paper aida:hasPercentageOfAcademia ?x .
    ?paper schema:creator ?author .
    FILTER(?x>80)
}
ORDER BY ?paper


The following query returns the number of publications in a topic (in this case Neural Networks) during the last five years. It can be used to analyse the trend of this topic in time.
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/>
PREFIX aida:<http://aida.kmi.open.ac.uk/ontology#>
PREFIX cso: <http://cso.kmi.open.ac.uk/topics/>

SELECT ?year (count(?paper) as ?n_publications)
FROM <http://aida.kmi.open.ac.uk/resource>
WHERE {
    ?paper aida:hasTopic cso:neural_networks .
    ?paper prism:publicationDate ?year .
    FILTER(xsd:integer(?year) >= 2016 && xsd:integer(?year) <= 2020)
} GROUP BY ?year
ORDER BY DESC(?year)


The following query returns the topic distribution of a given affiliation (in this case The Open University). It can be used to characterize an organization according to its relevant topics.
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX aida:<http://aida.kmi.open.ac.uk/ontology#>
PREFIX schema: <http://schema.org/>
SELECT ?topic (count(distinct(?paper)) as ?count)
FROM <http://aida.kmi.open.ac.uk/resource>
WHERE {
    ?paper schema:creator ?author .
    ?author schema:memberOf ?aff .
    ?aff foaf:name "the_open_university" .
    ?paper aida:hasTopic ?topic .
} GROUP BY ?topic
ORDER BY DESC(?count)


This query ranks affiliations according to their number of publications in a given topic (in this case Semantic Web):
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX aida:<http://aida.kmi.open.ac.uk/ontology#>
PREFIX cso: <http://cso.kmi.open.ac.uk/topics/>
PREFIX schema: <http://schema.org/>
SELECT ?aff ?aff_name (count(distinct(?paper)) as ?count)
FROM <http://aida.kmi.open.ac.uk/resource>
WHERE {
    ?paper aida:hasTopic cso:semantic_web .
    ?paper schema:creator ?author .
    ?author schema:memberOf ?aff .
    ?aff foaf:name ?aff_name
} GROUP BY ?aff ?aff_name
ORDER BY DESC(?count)
LIMIT 100


This query returns the academic affiliations that collaborates most (in terms of publication number) with industrial organizations:
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX aida:<http://aida.kmi.open.ac.uk/ontology#>
SELECT ?aff ?name (COUNT(?paper) as ?n_collaborations)
FROM <http://aida.kmi.open.ac.uk/resource>
WHERE {
    ?paper aida:hasAffiliationType "collaborative" .
    ?paper aida:hasAffiliation ?aff .
    ?aff aida:hasGridType "education" .
    ?aff foaf:name ?name .
} GROUP BY ?aff ?name
ORDER BY DESC(?n_collaborations)


The following query returns the DBpedia concepts associated to a given paper (id: 2300368847 in this case) using the mapping between CSO and DBpedia.
PREFIX aida: <http://aida.kmi.open.ac.uk/ontology#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX aidar: <http://aida.kmi.open.ac.uk/resource/>
SELECT *
FROM <http://aida.kmi.open.ac.uk/resource>
WHERE {
    aidar:2300368847 aida:hasTopic ?topic .
    ?topic owl:sameAs ?obj .
    FILTER(regex(str(?obj), "dbpedia" ) )
}